#!/bin/csh -f
#
# printbib - print a full bibtex bib file out
#
# David Kotz
#
# usage:
#  printbib bibfile...
#
# Then send the dvi file 'plain.dvi' to the printer
# (usage varies; try lpr -d plain.dvi)

if ($#argv == 0) then
	   echo usage: printbib bibfile...
	   exit 1
endif

if ($1:e == "bib") then
	   set files=($1:r)
echo $files
else
	   set files=($1)
endif

shift
foreach f ($*)
	   if ($f:e == "bib") then
	   	   set files="$files,$f:r"
	   else
	   	   set files="$files,$f"
	   endif
end

echo creating plain.tex for $files

cat > plain.tex <<EOF
\documentclass[11pt]{article}
\sloppy
\setlength{\textwidth}{6.5in}
\setlength{\textheight}{9in}
\setlength{\topmargin}{-0.5in}
\setlength{\oddsidemargin}{0pt}
\setlength{\evensidemargin}{0pt}
\newcommand{\eg}{e.g.}		% e.g.
\newcommand{\ie}{i.e.}		% i.e.
\newcommand{\etc}{etc.}		% etc.
\newcommand{\vs}{{\em vs.}}		% vs.
\begin{document}
\begin{center} \Large Bibliography files \large \\\\
EOF
echo $files.bib >> plain.tex
cat >> plain.tex <<EOF
\end{center}
\nocite{*}
\bibliographystyle{plain}
EOF

cat >> plain.tex <<EOF
\bibliography{$files.bib}
\end{document}
EOF

rm -f plain.{aux,log,dvi,bbl,blg}

set echo 
latex plain.tex
bibtex plain
latex plain.tex
latex plain.tex
kdvi plain.dvi
