!set n=$teller
!if $BEREKENINGEN=1
    bewerking=bewerking4.proc
!else
    bewerking=bewerking1.proc
!endif

max_aantal=7
min_aantal=2

!if $taal=nl
    nivo_title=Los de volgende vergelijking op (alle bewerkingen)
!else
    nivo_title=Solve the equation
!endif

!if $graad =0
    R=$teller
!else
    R=$graad
!endif    
!if $variabelen=1
    X$n=!randitem a,b,c,d,f,x,y,z,p,g,k,t,r,n,m
!else
    X$n=x
!endif
!if $breuken=0

    a=!randitem 2,3,4,5,6,7,8,9,10,11,12,13,14
    G$n=!randitem 2,3,4,5,6,7,8,9,10,11,12,13,14
    !if $R=1 
	# b+x=a*x => b=(a-1)x	
	b=$[($a-1)*$(G$n)]	    
	som$n=$b + $(X$n) \,\,\,=\,\,\,$a \cdot $(X$n) 
	extra$n=$b\,\,\,=\,\,$a \cdot $(X$n) - $(X$n) \Longrightarrow $b\,\,=$[$a-1]\cdot $(X$n) \Longrightarrow $(X$n) \,\,=\frac{$b}{$[$a-1]} = $(G$n)
     !exit
    !endif
	
    !if $R=2 
	# b-x=a*x => b=(a+1)x
	b=$[($a+1)*$(G$n)]
	som$n=$b - $(X$n) \,\,\,=\,\,\,$a \cdot $(X$n) 
	extra$n=$b \,=\,\,\,$a \cdot $(X$n) + $(X$n) \Longrightarrow $b \,\,=\,\,$[$a+1]\cdot $(X$n) \Longrightarrow $(X$n) \,\,=\frac{$b}{$[$a+1]} = $(G$n)
     !exit
    !endif

    !if $R=3 
	# b-cx=a*x => b=(a+c)x
	c=!randitem 2,3,4,5,6,7,8
	b=$[($a+$c)*$(G$n)]
	som$n=$b - $c\cdot $(X$n) \,\,\,=\,\,\,$a \cdot $(X$n) 
	extra$n=$b \,=\,\,\,$a \cdot $(X$n) + $c\cdot $(X$n) \Longrightarrow $b \,\,=\,\,$[$a+$c]\cdot $(X$n) \Longrightarrow $(X$n) \,\,=\frac{$b}{$[$a+$c]} = $(G$n)
     !exit
    !endif
    
    !if $R=4 
	# b+cx=a*x => b=(a-c)x
	c=!randitem 2,3,4,5,6,7,8
	b=$[($a-$c)*$(G$n)]
	som$n=$b + $c\cdot $(X$n) \,\,\,=\,\,\,$a \cdot $(X$n) 
	extra$n=$b \,=\,\,\,$a \cdot $(X$n) - $c\cdot $(X$n) \Longrightarrow $b \,\,=\,\,$[$a-$c]\cdot $(X$n) \Longrightarrow $(X$n) \,\,=\frac{$b}{$[$a-$c]} = $(G$n)
     !exit
    !endif
		
    !if $R>4 
	# (b+x)/x=a => xa=b+x => x(a-1)=b 
	b=$[$(G$n)*($a - 1)]
	som$n=\frac{$b + $(X$n)}{$(X$n)} = $a
	extra$n=$b +$(X$n) = $a \cdot $(X$n) \Longrightarrow  $b = $[$a -1]\cdot $(X$n) \Longrightarrow $(X$n)=$(G$n)
     !exit
    !endif
!else
    a=!randitem 1/2,1/3,1/4,1/5,1/6,1/7,1/8,1/9,1/10,2/3,3/4,2/5,3/5,4/5,5/6,2/7,3/7,4/7,5/7,6/7,7/8,5/8,3/8,4/9
    aa=!replace internal / by , in $a
    a1=!item 1 of $aa
    a2=!item 2 of $aa
    A=\frac{$a1}{$a2}
    b=!randitem 2,3,4,5,6,7,8,9,10,11,12,13,14
    !if $R=1
	#b*x=x + a => x=a/(b-1)
	gg=!exec pari B=$a/($b-1)\
	printtex(B)
	G$n=!line 1 of $gg
	G=!line 2 of $gg	    
	som$n=$b\cdot $(X$n)\,\,\,=\,\,\,$(X$n) + $A 
	extra$n=$[$b-1]\cdot $(X$n) = $A \Longrightarrow $(X$n)= \frac{1}{$[$b-1]} \cdot \frac{$a1}{$a2} = $G 
     !exit
    !endif
    
    !if $R=2 
	#b+x=a*x =>x=b/(a-1)	
	gg=!exec pari A=$b/($a-1)\
	printtex(A)
	G$n=!line 1 of $gg
	G=!line 2 of $gg	    
	som$n=$b + $(X$n) \,\,\,=\,\,\,$A \cdot $(X$n) 
	extra$n=$b\,\,\,=\,\,$A \cdot $(X$n) - $(X$n) \Longrightarrow $b\,\,=\frac{$[$a1-$a2]}{$a2} \cdot $(X$n) \Longrightarrow $(X$n)=$b\cdot \frac{$a2}{$[$a1-$a2]} = $G
	#a-1 =(a1-a2)/a2
     !exit	
    !endif
	
    !if $R=3 
	#b-x=a*x =>b=(a+1)x
	gg=!exec pari A=$b/($a+1)\
	printtex(A)
	G$n=!line 1 of $gg
	G=!line 2 of $gg	    
	som$n=$b - $(X$n) \,\,\,=\,\,\,$A \cdot $(X$n) 
	extra$n=$b\,\,\,=\,\,$A \cdot $(X$n) + $(X$n) \Longrightarrow $b\,\,=\frac{$[$a1+$a2]}{$a2}\cdot $(X$n) \Longrightarrow $(X$n)=$b\cdot \frac{$a2}{$[$a1+$a2]} = $G
     !exit
    !endif
	
    !if $R>3
	!if $R=4 
	    #a*x=x - b => x=-b/(a-1)
	    gg=!exec pari C=-1*$b/($a-1)\
	    printtex(C)
	    G$n=!line 1 of $gg
	    G=!line 2 of $gg	    
	    som$n=$A \cdot $(X$n)\,\,\,=\,\,\,$(X$n) - $b 
	    extra$n=$A \cdot $(X$n) - $(X$n) = - $b \Longrightarrow \frac{$[$a1 - $a2]}{$a2} \cdot $(X$n) = -$b \Longrightarrow $(X$n)=\frac{$a2}{$[$a1 - $a2]} \cdot - $b   = $G 
        !exit
    !else	
	#b*x=x + a => b= (x+a)/x
	G$n=!randitem 2,3,4,5,6,7,8,9,10,11,12,13,14
	a=!randitem 2,3,4,5,6,7,8,9,10,11,12,13,14
	bb=!exec pari A=($(G$n)+$a)/$(G$n)\
	printtex(A)
	b=!line 1 of $bb
	B=!line 2 of $bb
	som$n=$(X$n) \cdot $B \,\,\,=\,\,\,$(X$n) + $a
	extra$n=$(X$n)\cdot $B - $(X$n) = $a \Longrightarrow $(X$n) \,\,=\,\,\frac{$a}{$B - 1} =  $(G$n) 
     !exit
    !endif
!endif
