!set n=$teller
kans=1
!if $graad=0
    R=$teller
!else
    R=$graad
!endif  
kleuren=!shuffle red@rooie,blue@blauwe,green@groene,yellow@gele
opgave$n=$empty
bewerking=bewerking1.proc
nivo_title=Trekken zonder terugleggen
vaas=!randitem vaas,bak,aquarium
ballen=!randitem ballen,knikkers,kogels,kogeltjes
k1=!item 1 of $kleuren
k2=!item 2 of $kleuren
k1=!replace internal @ by , in $k1
k2=!replace internal @ by , in $k2
kleur1=!item 2 of $k1
color1=!item 1 of $k1
kleur2=!item 2 of $k2
color2=!item 1 of $k2
keuze=!randitem 0,1
kans=1
!if $R=1
    a=!randitem 3,4,5,6,7
    b=!randitem 3,4,5,6,7
    tot=$[$a+$b]
    !if $keuze=1
	aantal=!randint 2,$a
	kleur=$kleur1
	c=$a
    !else
	aantal=!randint 2,$b
	kleur=$kleur2
	c=$b
    !endif
    som=1
    SOM=1
    !for p=1 to $aantal
	som=($som)*(($c+1-$p)/($tot+1-$p))
	SOM=$SOM*$[$c+1-$p]/$[$tot+1-$p]
    !next p	
    GOED$n=!exec pari $som
    goed$n=!htmlmath $SOM = $(GOED$n) &asymp; $[$(GOED$n)]
    somtekst$n=We hebben een $vaas met $a $kleur1 en $b $kleur2 $ballen .<br>\
    Je trekt er <em>aselect</em> $aantal $ballen uit <em>zonder terugleggen</em>.<br>\
    Wat is de kans bij deze trekking op $aantal $kleur $ballen .\
    <br><small><em>Rond af op tenminste 6 decimalen</em></small>
    opgave$n=$empty
    !readproc nivo/plaatje.proc
 !exit
!endif
!if $R=2
    a=!randitem 3,4,5,6,7
    b=!randitem 3,4,5,6,7
    tot=$[$a+$b]
    aantal=!randint 2,$b
    som=(($a*($aantal+1))/$tot)
    SOM=$[$aantal+1]*$a/$tot
    !for p=1 to $aantal
	som=($som)*(($b+1-$p)/($tot-$p))
	SOM=$SOM*$[$b+1-$p]/$[$tot-$p]
    !next p	
    GOED$n=!exec pari $som
    goed$n=!htmlmath $SOM = $(GOED$n) = &asymp; $[$(GOED$n)]

    somtekst$n=We hebben een $vaas met $a $kleur1 en $b $kleur2 $ballen .<br>\
    Je trekt er <em>aselect</em> $[$aantal+1] $ballen uit <em>zonder terugleggen</em>.<br>\
    Wat is de kans bij deze trekking op &eacute;&eacute;n  $kleur1 en $aantal $kleur2 $ballen .\
    <br><small><em>Rond af op tenminste 6 decimalen</em></small>
    !readproc nivo/plaatje.proc
 !exit
!endif
!if $R=3
    a=!randitem 3,4,5,6,7
    b=!randitem 3,4,5,6,7
    tot=$[$a+$b]
    a1=!randint 2,$a
    b1=!randint 2,$b
    # havo methode
    TT=factorial($a)*factorial($b)*factorial($a1+$b1)*factorial($a+$b-$a1-$b1)
    NN=factorial($a1)*factorial($b1)*factorial($a-$a1)*factorial($b-$b1)*factorial($a+$b)
    GOED$n=$[($TT)/($NN)]
    goed$n=!htmlmath $(GOED$n)
    somtekst$n=We hebben een $vaas met $a $kleur1 en $b $kleur2 $ballen .<br>\
    Je trekt er <em>aselect</em> $[$a1+$b1] $ballen uit <em>zonder terugleggen</em>.<br>\
    Wat is de kans bij deze trekking op $a1 $kleur1 en $b1 $kleur2 $ballen .\
    <br><small><em>Rond af op tenminste 6 decimalen</em></small>
    !readproc nivo/plaatje.proc
 !exit
!endif
!if $R>3
    a=!randitem 6,7,8,9,10,11,12,13,14,15
    b=!randitem 10,11,12,13,14,15
    tot=$[$a+$b]
    a1=!randitem 3,4,5
    b1=!randint 2,3,4,5
    aantal=$[$a1+$b1]
    g1=$[(factorial($b)*factorial($tot - $aantal))/(factorial($b-$aantal)*factorial($tot))]
    g2=$[$g1 + ($aantal*$a*factorial($b)*factorial($tot-$aantal))/(factorial($b-$aantal+1)*factorial($tot))]
    g3=$[$g2 + ($a*($a-1)*$aantal*($aantal-1)*factorial($tot-$aantal)*factorial($b))/(2*factorial($b-$aantal+2)*factorial($tot))]
    !if $keuze=1
        a11=!randitem 1,2                 
	hoogstens=hoogstens
	!if $a11=1
	    GOED$n=$g2
	    goed$n=!htmlmath P(0 $kleur1) + P(1 $kleur1)  &asymp; $(GOED$n)
	!else
	    GOED$n=$g3
	    goed$n=!htmlmath P(0 $kleur1) + P(1 $kleur1) + P(2 $kleur1) &asymp; $(GOED$n)
	!endif    
    !else
        a11=!randitem 1,2,3                 
	hoogstens=ten minste
	!if $a11=1
	    GOED$n=$[1-$g1]
	    goed$n=!htmlmath 1-P(0 $kleur1) &asymp; $(GOED$n)
	!else
	    !if $a11=2
		GOED$n=$[1-$g2]
		goed$n=!htmlmath 1 - P(0 $kleur1) - P(1 $kleur1)  &asymp; $(GOED$n)
	    !else
		GOED$n=$[1-$g3]	    
		goed$n=!htmlmath 1 - P(0 $kleur1) - P(1 $kleur1) - P(2 $kleur1)  &asymp; $(GOED$n)
	    !endif	    
	!endif
    !endif		
    # havo methode
    somtekst$n=We hebben een $vaas met $a $kleur1 en $b $kleur2 $ballen .<br>\
    Je trekt er <em>aselect</em> $aantal $ballen uit <em>zonder terugleggen</em>.<br>\
    Wat is de kans bij deze trekking op <b><tt>$hoogstens</tt></b> $a11 $kleur1 ?\
    <br><small><em>Rond af op tenminste 6 decimalen</em></small>
    !readproc nivo/plaatje.proc
 !exit
!endif

